Classification Attributes

Get the classification attributes of the classes in the DEXPI Information Model.

Variables

cls
The class for which the attribute is declared.
attribute
Name of the attribute.
rdl
The RDL reference associated with the attribute in a DEXPI-compliant Proteus file.
classification_type
The classification type of the attribute. See Classification Types and Values.
description

Optional. A description of the attribute.

Note

Descriptions may contain markup that is used to build the official PDF version of the DEXPI Specification. In the cached HTML, CSV, and Excel results below, this markup has been removed for better readability. For example, a description such as The \labeledref[class:]{ControlledActuator} of the <owner> will be shown as The ControlledActuator of the ActuatingSystem.

is_proteus_generic_attribute
A boolean indicating if the attribute is represented as a <GenericAttribute> in a DEXPI-compliant Proteus XML file.

SPARQL Query

PREFIX meta: <http://sandbox.dexpi.org/meta/>

SELECT ?cls ?attribute ?rdl ?classification_type ?description ?is_proteus_generic_attribute
WHERE
{
    [] a meta:ModelClass;
        meta:simpleLabel ?cls;
        meta:hasDeclaration ?decl.

    ?decl a meta:AttributeDeclaration;
        meta:hasTargetType [
            a meta:ClassificationType;
            meta:simpleLabel ?classification_type];
        meta:simpleLabel ?attribute.

    OPTIONAL
    {
        ?decl meta:rdl ?rdl.
    }

    OPTIONAL
    {
        ?decl meta:description ?description.
    }

    BIND
    (
        EXISTS
        {
            ?decl meta:proteusImplementation [
                a meta:StandardGenericAttribute]
        }
        AS ?is_proteus_generic_attribute
    )
}
ORDER BY ?cls ?attribute

Partial SPARQL Results

The full query result contains 43 rows. The first rows are as follows:

cls attribute rdl classification_type description is_proteus_generic_attribute
Chamber ChamberFunctionSpecialization http://sandbox.dexpi.org/rdl/ChamberFunctionSpecialization ChamberFunctionClassification A specialization indicating the function of the Chamber. true
CheckValve HeatTracingTypeSpecialization http://sandbox.dexpi.org/rdl/HeatTracingTypeSpecialization HeatTracingTypeClassification A specialization indicating the heat tracing type related to the CheckValve. true
ControlledActuator FailActionSpecialization http://sandbox.dexpi.org/rdl/FailActionSpecialization FailActionClassification The fail action of the ControlledActuator. true
FlameArrestor DetonationProofArtefactSpecialization http://sandbox.dexpi.org/rdl/DetonationProofArtefactSpecialization DetonationProofArtefactClassification A specialization indicating if the FlameArrestor is detonation-proof. true
FlameArrestor ExplosionProofArtefactSpecialization http://sandbox.dexpi.org/rdl/ExplosionProofArtefactSpecialization ExplosionProofArtefactClassification A specialization indicating if the FlameArrestor is explosion-proof. true
... ... ... ... ... ...

Full SPARQL Results

Cached

Note

The cached results below are guaranteed to correspond to DEXPI P&ID Specification 1.2.

Cached results:

Online

Note

Online results can change! There is no guarantee that these results correspond to DEXPI P&ID Specification 1.2.

Get results online from DEXPI SPARQL server at http://endpoint.dexpi.org: