String Attributes Including Inherited Attributes

Get the string attributes of the classes in the DEXPI Information Model. For each class, also the inherited attributes are included.

Variables

cls
The class for which the attribute is declared, either directly or by inheritance from one of its super classes.
attribute
Name of the attribute.
decl_cls
The class for which the attribute is directly declared.
description

Optional. A description of the attribute.

Note

Descriptions may contain markup that is used to build the official PDF version of the DEXPI Specification. In the cached HTML, CSV, and Excel results below, this markup has been removed for better readability. For example, a description such as The \labeledref[class:]{ControlledActuator} of the <owner> will be shown as The ControlledActuator of the ActuatingSystem.

rdl
The RDL reference associated with the attribute in a DEXPI-compliant Proteus file.
is_proteus_generic_attribute
A boolean indicating if the attribute is represented as a <GenericAttribute> in a DEXPI-compliant Proteus XML file.

SPARQL Query

PREFIX meta: <http://sandbox.dexpi.org/meta/>

SELECT ?cls ?attribute ?decl_cls ?description ?rdl ?is_proteus_generic_attribute
WHERE
{
    [] a meta:ModelClass;
        meta:simpleLabel ?cls;
        meta:subClassOf* [
            meta:hasDeclaration ?decl;
            meta:simpleLabel ?decl_cls ].

    ?decl a meta:AttributeDeclaration;
        meta:hasTargetType [a meta:StringType];
        meta:simpleLabel ?attribute.

    OPTIONAL
    {
        ?decl meta:description ?description.
    }

    OPTIONAL
    {
        ?decl meta:rdl ?rdl.
    }

    BIND
    (
        EXISTS
        {
            ?decl meta:proteusImplementation [
                a meta:StandardGenericAttribute]
        }
        AS ?is_proteus_generic_attribute
    )
}
ORDER BY ?cls_label ?decl_label

Partial SPARQL Results

The full query result contains 819 rows. The first rows are as follows:

cls attribute decl_cls description rdl is_proteus_generic_attribute
ActuatingFunction ActuatingFunctionNumberAssignmentClass ActuatingFunction An identifier for the ActuatingFunction. It usually contains the identifier of the ProcessInstrumentationFunction that includes the ActuatingFunction (see ProcessInstrumentationFunctionNumberAssignmentClass). http://sandbox.dexpi.org/rdl/ActuatingFunctionNumberAssignmentClass true
ActuatingSystem ActuatingSystemNumberAssignmentClass ActuatingSystem The number of the ActuatingSystem http://sandbox.dexpi.org/rdl/ActuatingSystemNumberAssignmentClass true
ActuatingSystem TypicalInformationAssignmentClass ActuatingSystem Typical information about the ActuatingSystem. http://sandbox.dexpi.org/rdl/TypicalInformationAssignmentClass true
Agitator EquipmentDescriptionAssignmentClass Equipment A short desciption of the Equipment in natural language. So far, there is no support for descriptions in different languages. http://data.posccaesar.org/rdl/RDS2181987301 true
Agitator TagNameAssignmentClass TaggedPlantItem The tag number of the TaggedPlantItem. See also <owner.TagNamePrefixAssignmentClass>, <owner.TagNameSequenceNumberAssignmentClass>, and <owner.TagNameSuffixAssignmentClass>. http://sandbox.dexpi.org/rdl/TagNameAssignmentClass false
... ... ... ... ... ...

Full SPARQL Results

Cached

Note

The cached results below are guaranteed to correspond to DEXPI P&ID Specification 1.2.

Cached results:

Online

Note

Online results can change! There is no guarantee that these results correspond to DEXPI P&ID Specification 1.2.

Get results online from DEXPI SPARQL server at http://endpoint.dexpi.org: