Integer Attributes Including Inherited Attributes

Get the integer attributes of the classes in the DEXPI Information Model. For each class, also the inherited attributes are included.

Variables

cls
The class for which the attribute is declared, either directly or by inheritance from one of its super classes.
attribute
Name of the attribute.
decl_cls
The class for which the attribute is directly declared.
description

Optional. A description of the attribute.

Note

Descriptions may contain markup that is used to build the official PDF version of the DEXPI Specification. In the cached HTML, CSV, and Excel results below, this markup has been removed for better readability. For example, a description such as The \labeledref[class:]{ControlledActuator} of the <owner> will be shown as The ControlledActuator of the ActuatingSystem.

rdl
The RDL reference associated with the attribute in a DEXPI-compliant Proteus file.
is_proteus_generic_attribute
A boolean indicating if the attribute is represented as a <GenericAttribute> in a DEXPI-compliant Proteus XML file.

SPARQL Query

PREFIX meta: <http://sandbox.dexpi.org/meta/>

SELECT ?cls ?attribute ?decl_cls ?description ?rdl ?is_proteus_generic_attribute
WHERE
{
    [] a meta:ModelClass;
        meta:simpleLabel ?cls;
        meta:subClassOf* [
            meta:hasDeclaration ?decl;
            meta:simpleLabel ?decl_cls ].

    ?decl a meta:AttributeDeclaration;
        meta:hasTargetType [a meta:IntegerType];
        meta:simpleLabel ?attribute.

    OPTIONAL
    {
        ?decl meta:description ?description.
    }

    OPTIONAL
    {
        ?decl meta:rdl ?rdl.
    }

    BIND
    (
        EXISTS
        {
            ?decl meta:proteusImplementation [
                a meta:StandardGenericAttribute]
        }
        AS ?is_proteus_generic_attribute
    )
}
ORDER BY ?cls_label ?decl_label

Partial SPARQL Results

The full query result contains 7 rows. The first rows are as follows:

cls attribute decl_cls description rdl is_proteus_generic_attribute
ColumnPackingsArrangement NumberOfPackings ColumnPackingsArrangement The number of packings in the ColumnPackingsArrangement. http://sandbox.dexpi.org/rdl/NumberOfPackings true
ColumnTraysArrangement NumberOfTrays ColumnTraysArrangement The number of trays in the ColumnTraysArrangement. http://sandbox.dexpi.org/rdl/NumberOfTrays true
FilterUnit NumberOfFilterElements FilterUnit   http://sandbox.dexpi.org/rdl/NumberOfFilterElements true
MetaData TotalNumberOfSheets MetaData The total number of sheets. http://sandbox.dexpi.org/rdl/TotalNumberOfSheets true
MixingElementAssembly NumberOfMixingElements MixingElementAssembly The number of mixing elements in the MixingElementAssembly. http://sandbox.dexpi.org/rdl/NumberOfMixingElements true
... ... ... ... ... ...

Full SPARQL Results

Cached

Note

The cached results below are guaranteed to correspond to DEXPI P&ID Specification 1.2.

Cached results:

Online

Note

Online results can change! There is no guarantee that these results correspond to DEXPI P&ID Specification 1.2.

Get results online from DEXPI SPARQL server at http://endpoint.dexpi.org: